load("@io_bazel_rules_go//go:def.bzl", "go_binary", "go_library")

go_library(
    name = "hyperkube_lib",
    srcs = ["main.go"],
    importpath = "source.monogon.dev/metropolis/node/kubernetes/hyperkube",
    visibility = ["//visibility:private"],
    deps = [
        "@com_github_spf13_cobra//:cobra",
        "@io_k8s_component_base//cli",
        "@io_k8s_component_base//metrics/prometheus/restclient",
        "@io_k8s_component_base//metrics/prometheus/version",
        "@io_k8s_kubernetes//cmd/kube-apiserver/app",
        "@io_k8s_kubernetes//cmd/kube-controller-manager/app",
        "@io_k8s_kubernetes//cmd/kube-scheduler/app",
        "@io_k8s_kubernetes//cmd/kubelet/app",
    ],
)

stamp_pkgs = [
    "k8s.io/component-base/version",
    "k8s.io/client-go/pkg/version",
]

stamp_vars = [
    "gitMajor",
    "gitMinor",
    "gitVersion",
    "gitCommit",
    "gitTreeState",
    "buildDate",
]

go_binary(
    name = "hyperkube",
    embed = [":hyperkube_lib"],
    stampsrcs = ["//build:stabler_status"],
    visibility = ["//metropolis/node:__pkg__"],
    x_defs = {"%s.%s" % (pkg, var): "{STABLER_KUBERNETES_%s}" % var for pkg in stamp_pkgs for var in stamp_vars},
)