diff --git a/metropolis/cli/metroctl/BUILD.bazel b/metropolis/cli/metroctl/BUILD.bazel
index 960c220..f013c42 100644
--- a/metropolis/cli/metroctl/BUILD.bazel
+++ b/metropolis/cli/metroctl/BUILD.bazel
@@ -1,4 +1,18 @@
 load("@io_bazel_rules_go//go:def.bzl", "go_binary", "go_library", "go_test")
+load(":defs.bzl", "buildkind")
+
+buildkind(
+    name = "buildkind",
+    build_setting_default = "full",
+)
+
+# True if user requested a lite build via --//metropolis/cli/metroctl:buildkind=lite .
+config_setting(
+    name = "buildkind_lite",
+    flag_values = {
+        ":buildkind": "lite",
+    },
+)
 
 go_library(
     name = "metroctl_lib",
@@ -17,10 +31,13 @@
         "table.go",
         "table_node.go",
     ],
-    data = [
-        "//metropolis/installer:kernel",  #keep
-        "//metropolis/node:bundle",
-    ],
+    data = select({
+        ":buildkind_lite": [],
+        "//conditions:default": [
+            "//metropolis/installer:kernel",
+            "//metropolis/node:bundle",
+        ],
+    }),
     importpath = "source.monogon.dev/metropolis/cli/metroctl",
     visibility = ["//visibility:private"],
     deps = [
diff --git a/metropolis/cli/metroctl/defs.bzl b/metropolis/cli/metroctl/defs.bzl
new file mode 100644
index 0000000..ce75195
--- /dev/null
+++ b/metropolis/cli/metroctl/defs.bzl
@@ -0,0 +1,19 @@
+BuildKindProvider = provider(fields = ['type'])
+
+def _impl(ctx):
+    values = ['full', 'lite'] 
+    value = ctx.build_setting_value
+    if value not in values:
+        fail(str(ctx.label) + " build setting allowed to take values {full, lite} but was set to " + value)
+
+    return BuildKindProvider(type = value)
+
+buildkind = rule(
+    implementation = _impl,
+    build_setting = config.string(flag = True),
+    doc = """
+        Build kind for userspace tools, either full (will have a direct
+        dependency on data files) or lite (will not have a direct dependency on
+        data files and will not attempt to load them).
+    """,
+)